Imagina que tienes una fila de casilleros numerados, como los de una escuela o gimnasio. Cada casillero tiene un número (1, 2, 3, etc.) que lo identifica, y en cada uno puedes guardar un objeto, como un libro, una mochila o ropa. Si necesitas buscar algo, solo necesitas saber el número del casillero donde está guardado.
De la misma manera, un array unidimensional es como esa fila de casilleros: es una estructura que organiza datos en posiciones numeradas. Cada dato tiene un lugar específico que puedes encontrar usando su número, llamado índice.
Los arrays unidimensionales (también conocidos como vectores o arreglos unidimensionales), son una de las estructuras de datos más básicas pero importantísimas en programación. Nos permiten almacenar múltiples valores relacionados bajo un único nombre, organizados de forma secuencial. En este artículo aprenderemos manejar arrays como colecciones de datos y realizar operaciones básicas como declaración, acceso, modificación, recorrido, ordenamiento y cálculos sencillos.
- Tamaño fijo: El tamaño del array debe definirse antes de su uso.
- Acceso por índices: Los elementos del array se acceden mediante su posición, empezando desde 1 en PSeInt.
- Elementos homogéneos: Todos los elementos del array deben ser del mismo tipo, como enteros, reales o cadenas.
En este blog, usaremos la indexación de los arreglos desde 1, ya que es la más común en entornos educativos y la que viene configurada por defecto en PSeInt. Más información
Declaración
- En PSeInt, los arrays se declaran utilizando la palabra clave
Dimension, seguida del nombre del array y los límites dentro de paréntesis o corchetes.
Sintaxis
Dimension <nombre_del_array>(<tamaño>)
Dimension <nombre_del_array>[<tamaño>]
El tipo de dato de los elementos en el array se define al momento de usarlos, o implícitamente a través de las operaciones realizadas.
Ejemplo 1: Declaray arrays unidimensional de diferente cantidad de elementos
Array de enteros
Se puede declarar un array unidimensional llamado numeros con espacio para 5 elementos de cualquiera de las dos formas mostradas. No se especifica el tipo de datos en la declaración ya que este se asume directamente cuando se empiecen a asignar sus valores.
Dimension numeros[5]
Dimension numeros(5)
Cuando trabajes con arrays unidimensionales, imagina una fila de cuadros o celdas numeradas, como la que se muestra en la imagen. Cada cuadro representa un espacio en el array donde puedes almacenar un valor.
- El nombre del array (en este caso,
numeros) identifica toda la fila de celdas. - Cada índice dentro del array está numerada, empezando desde el índice 1 en PSeInt.
- Puedes usar el índice para leer o modificar el valor almacenado en esa posición específica.
Esta forma de visualizar un array como una tabla te ayudará a entender mejor cómo acceder y trabajar con los datos en tu programa. Cada vez que declares un array, imagina esta fila de espacios para organizar mejor tus datos.
También puedes imaginarlo como una columna de espacios, según gustes:
Array de reales (números con decimales):
Dimension precios(10)
Este array puede almacenar 10 valores decimales, como precios de productos.
Array de cadenas (textos):
Dimension nombres(3)
Este array puede almacenar 3 textos, como nombres de personas.
Array de valores lógicos (verdadero o falso):
Dimension respuestas(4)
Este array puede almacenar 4 valores lógicos, como respuestas a preguntas de tipo «Sí o No».
Array de calificaciones:
Dimension calificaciones(6)
Este array puede almacenar 6 calificaciones, las cuales pueden ser reales o enteros dependiendo de cómo las utilices.
Nota:
- Aunque los ejemplos usan nombres intuitivos como
nombresocalificaciones, puedes usar cualquier identificador que describa los datos que almacenarás en el array siempre y cuando sea un identificador válido (estar formados por letras, números y/o guion bajo (_), iniciar siempre con una letra, no contener símbolos como @, #, ▼,, =, etc, no contener eñes (ñ ó Ñ) y no tener espacios en blancos).
- En muchos lenguajes de programación, como C, Python o Java, los índices de los arrays empiezan desde 0, es decir, la primera posición de un array se identifica como índice
0. Sin embargo, en PSeInt, los índices comienzan desde 1.
Acceso y Modificación de Elementos en un Array
Para acceder o modificar un elemento en un array, se utiliza su índice, que comienza desde 1 en PSeInt.
Ejemplo 2: Declaración y acceso a elementos
Declarar un array de 5 números y asignar valores a sus elementos.
Proceso DeclaracionYAcceso
// Declaramos un array de tamaño 5
Dimension numeros(5)
// Asignamos valores a los elementos del array
numeros(1) <- 10
numeros(2) <- 20
numeros(3) <- 30
numeros(4) <- 40
numeros(5) <- 50
// Mostramos los valores en pantalla
Escribir "El primer número es: ", numeros(1)
Escribir "El último número es: ", numeros(5)
FinProceso
Recorrido sobre un Array
Para recorrer los elementos de un array, se utilizan estructuras repetitivas como Para o Mientras.
Ejemplo 3: Llenar y mostrar un array
Crear un programa que solicite al usuario ingresar 5 números y luego los muestre en pantalla.
🖥️ Peudocódigo
Proceso LlenarYMostrar
// Declaramos un array de tamaño 5
Dimension numeros(5)
// Llenamos el array con valores ingresados por el usuario
Para i <- 1 Hasta 5 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Mostramos los valores almacenados en el array
Escribir "Los números ingresados son:"
Para i <- 1 Hasta 5 Hacer
Escribir numeros(i)
FinPara
FinProceso
▶️ Ejecución
Variables Individuales vs. Arrays
Arrays de elementos enteros:
Sin arrays: Supongamos que queremos almacenar los nombres de 5 estudiantes y mostrarlos en pantalla.
Definir edad1, edad2, edad3, edad4, edad5 Como Entero
edad1 <- 20
edad2 <- 25
edad3 <- 30
edad4 <- 35
edad5 <- 40
Cada variable se almacena en una posición de memoria diferente y aleatoria por lo que no están relacionadas entre sí, lo que puede dificultar su manejo al trabajar con grandes cantidades de datos.
Con arrays: Usando un array, podemos simplificar la tarea de trabajar con muchos datos.
Dimension edades(5)
edades(1) <- 20
edades(2) <- 25
edades(3) <- 30
edades(4) <- 35
edades(5) <- 40
Ahora que todas las edades están almacenadas en una sola estructura, cada uno de sus elementos serán accesibles mediante índices. Esto facilita recorrer los valores, calcular promedios, buscar elementos y más, como veremos en los ejemplos posteriores.
Arrays de elementos de tipo Cadena:
Sin arrays: Supongamos que queremos almacenar los nombres de 5 estudiantes y mostrarlos en pantalla.
Proceso EstudiantesSinArray
Definir nombre1, nombre2, nombre3, nombre4, nombre5 Como Cadena
nombre1 <- "Ana"
nombre2 <- "Carlos"
nombre3 <- "Luis"
nombre4 <- "Maria"
nombre5 <- "Sofia"
Escribir nombre1
Escribir nombre2
Escribir nombre3
Escribir nombre4
Escribir nombre5
FinProceso
Con arrays: Declaramos un array de 5 elementos. Cada elemento se accede con un íncide y se le asigna su valor de tipo cadena.
Proceso EstudiantesConArray
Dimension nombres(5)
nombres(1) <- "Ana"
nombres(2) <- "Carlos"
nombres(3) <- "Luis"
nombres(4) <- "Maria"
nombres(5) <- "Sofia"
Para i <- 1 Hasta 5 Hacer
Escribir nombres(i)
FinPara
FinProceso
Ventajas de usar Arrays en lugar de variables individuales
Cuando declaramos variables de forma individual, cada una ocupa una posición de memoria independiente. Por lo que, aunque sus valores puedan estar relacionados, el programador debe recordar y manejar cada variable por separado, lo cual es más complicado y se pueden cometer errores.
Por otro lado, al usar un array, todas las posiciones ocupan un bloque continuo de memoria. Esto, además de mejorar la organización, también permite acceder a los valores de manera más eficiente mediante índices. En términos prácticos:
- Variables individuales: Cada posición de memoria tiene un nombre único (ejemplo:
edad1,edad2). - Array: Una única estructura con un nombre común y acceso a través de índices (ejemplo:
edades(1),edades(2)).
Por lo tanto los arrays son las estructuras de datos ideales para trabajar con grandes cantidades de datos relacionados y del mismo tipo, como listas de edades, nombres o valores numéricos.
Operaciones con Arrays
Ejemplo 4: Sumar los elementos de un array
Crear un programa que calcule la suma de los elementos de un array.
🖥️ Peudocódigo
Proceso SumarElementos
// Declaramos un array de tamaño 5
Dimension numeros(5)
Definir suma Como Entero
suma <- 0
// Llenamos el array con valores ingresados por el usuario
Para i <- 1 Hasta 5 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Calculamos la suma de los elementos
Para i <- 1 Hasta 5 Hacer
suma <- suma + numeros(i)
FinPara
Escribir "La suma de los elementos es: ", suma
FinProceso
▶️ Ejecución
Ejercicios Resueltos
Ejemplo 5: Encontrar el mayor elemento
Crear un programa que encuentre el mayor número en un array de 10 elementos.
🖥️ Peudocódigo
Proceso MayorElemento
Dimension numeros(10)
Definir mayor Como Entero
// Llenamos el array
Para i <- 1 Hasta 10 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Encontramos el mayor elemento
mayor <- numeros(1)
Para i <- 2 Hasta 10 Hacer
Si numeros(i) > mayor Entonces
mayor <- numeros(i)
FinSi
FinPara
Escribir "El número mayor es: ", mayor
FinProceso
▶️ Ejecución
Ejemplo 6: Contar números pares
Diseñar un programa que cuente cuántos números pares hay en un array de 10 elementos.
🖥️ Peudocódigo
Proceso ContarPares
Dimension numeros(10)
Definir contador Como Entero
contador <- 0
// Llenamos el array
Para i <- 1 Hasta 10 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Contamos los números pares
Para i <- 1 Hasta 10 Hacer
Si numeros(i) MOD 2 = 0 Entonces
contador <- contador + 1
FinSi
FinPara
Escribir "La cantidad de números pares es: ", contador
FinProceso
▶️ Ejecución
Ejemplo 7: Calcular el promedio de los elementos de un array
Diseñar un programa que lea 6 números, calcule su promedio y muestre el resultado.
🖥️ Peudocódigo
Proceso CalcularPromedio
Dimension numeros(6)
Definir suma, promedio Como Real
suma <- 0
// Llenamos el array con valores ingresados por el usuario
Para i <- 1 Hasta 6 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Calculamos la suma de los elementos
Para i <- 1 Hasta 6 Hacer
suma <- suma + numeros(i)
FinPara
// Calculamos el promedio
promedio <- suma / 6
// Mostramos el resultado
Escribir "El promedio de los números es: ", promedio
FinProceso
▶️ Ejecución
Ejemplo 8: Invertir los elementos de un array
Crear un programa que invierta los elementos de un array de 5 números.
🖥️ Peudocódigo
Proceso InvertirArray
Dimension numeros(5), invertido(5)
// Llenamos el array con valores ingresados por el usuario
Para i <- 1 Hasta 5 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Invertimos el array
Para i <- 1 Hasta 5 Hacer
invertido(6 - i) <- numeros(i)
FinPara
// Mostramos el array invertido
Escribir "El array invertido es:"
Para i <- 1 Hasta 5 Hacer
Escribir invertido(i)
FinPara
FinProceso
▶️ Ejecución
Ejemplo 9: Determinar la frecuencia de un número en un array
Diseñar un programa que determine cuántas veces aparece un número dado en un array de 8 elementos.
🖥️ Peudocódigo
Proceso ContarFrecuencia
Dimension numeros(8)
Definir numeroBuscado, contador Como Entero
contador <- 0
// Llenamos el array con valores ingresados por el usuario
Para i <- 1 Hasta 8 Hacer
Escribir "Ingrese el número en la posición ", i, ":"
Leer numeros(i)
FinPara
// Solicitamos el número a buscar
Escribir "Ingrese el número que desea buscar:"
Leer numeroBuscado
// Contamos la frecuencia del número buscado
Para i <- 1 Hasta 8 Hacer
Si numeros(i) = numeroBuscado Entonces
contador <- contador + 1
FinSi
FinPara
// Mostramos el resultado
Escribir "El número ", numeroBuscado, " aparece ", contador, " veces en el array."
FinProceso
▶️ Ejecución
🎯 ¡Tu idea puede aparecer en la próxima clase!
¿Tienes una duda específica, un ejercicio que no entiendes o un tema que debería explicarse mejor?
Envíalo ahora y podrías ver tu nombre en el artículo. Además, los primeros en sugerir temas entran a una lista especial de colaboradores.
